@echo off
setlocal enabledelayedexpansion
title GRAVADOR KAROS
cd /d "%~dp0"

echo.
echo   ================================
echo    GRAVADOR DE SESSAO -- KAROS
echo   ================================
echo.

if not exist hook.dll goto semficheiro
if not exist injector.exe goto semficheiro

echo   1. FECHA o jogo, se estiver aberto.
echo   2. Carrega uma tecla aqui.
echo   3. Abre o jogo e joga normalmente.
echo.
echo   Quando fechares o jogo, eu trato do resto.
echo.
pause

del "C:\RoshHook\traffic.log" >nul 2>&1

echo.
echo   A ligar o gravador...
start "" injector.exe

echo.
echo   ####################################
echo   #     PODES ABRIR O JOGO AGORA     #
echo   ####################################
echo.
echo   Nao feches esta janela enquanto jogas.
echo.

echo   A espera do jogo abrir...
:esperarabrir
tasklist /fi "imagename eq AMo.exe" 2>nul | find /i "AMo.exe" >nul
if errorlevel 1 (
  timeout /t 2 >nul
  goto esperarabrir
)
echo   Jogo aberto. A gravar -- podes jogar.

:esperarfechar
timeout /t 5 >nul
tasklist /fi "imagename eq AMo.exe" 2>nul | find /i "AMo.exe" >nul
if not errorlevel 1 goto esperarfechar

echo.
echo   Jogo fechado. A guardar a gravacao...

if not exist "C:\RoshHook\traffic.log" goto semgravacao

set "PASTA=%USERPROFILE%\Desktop\CapturaKaros"
if not exist "!PASTA!" mkdir "!PASTA!"

set "STAMP=%date:~-4%%date:~3,2%%date:~0,2%_%time:~0,2%%time:~3,2%"
set "STAMP=!STAMP: =0!"
set "DEST=!PASTA!\karos_!STAMP!.log"

copy /y "C:\RoshHook\traffic.log" "!DEST!" >nul

echo.
echo   ================================
echo    PRONTO
echo   ================================
echo.
echo   O ficheiro esta em:
echo     Area de Trabalho \ CapturaKaros
echo.
echo   Comprime e envia. Diz-me a tua classe.
echo.
start "" "!PASTA!"
pause
exit /b 0

:semgravacao
echo.
echo   Nao ficou gravacao. O jogo abriu depressa demais?
echo   Tenta de novo: GRAVAR primeiro, jogo depois.
echo.
pause
exit /b 1

:semficheiro
echo.
echo   FALTAM FICHEIROS nesta pasta.
echo   Descompacta o ZIP todo primeiro.
echo.
pause
exit /b 1
